VBA实现Excel的数据透视表
前言本节会先容通过VBA的PivotCaches.Create方法实现Excel创建新的数据透视表、修改原有的数据透视表的数据源以及刷新数据透视表内容。
本节测试内容以下表信息为例
https://i-blog.csdnimg.cn/direct/5a79bd018e7643099c6cbb7279270fca.png
1、创建数据透视表
语法：PivotCaches.Create(SourceType, , )
阐明：
SourceType:必填参数，可以是以下 XlPivotTableSourceType 常量之一： xlConsolidation、 xlDatabase 或 xlExternal
SourceData:非必填，新数据透视表缓存的数据。
Version:版本，非必填，可以是常量xlPivotTableVersion2000，对应Excel 2000，也可以是xlPivotTableVersion10、xlPivotTableVersion11、xlPivotTableVersion12、xlPivotTableVersion14、xlPivotTableVersion15分别表现Excel 2002、2003、2007、2010、2013
示例：
根据上表内容，在原sheet2上创建一个数据透视表，起始位置为J1，透视表设置举动名称、产品编号，列设置为生产年代，值为销售数目求和，完备的代码如下：
Sub CreatePivot()
' 声明工作簿、工作表变量
Dim wb As Workbook
Dim ws As Worksheet
' 声明数据源、透视表目标起始位置、数据透视表变量
Dim dataSource As Range
Dim datePivot As Range
Dim newPivotAs PivotTable
'设置工作簿为当前文件
Set wb = ThisWorkbook
Set ws = ThisWorkbook.Worksheets("Sheet2")
' 通过A列获取最大行数
Dim lastRow As Long
lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
' 定义数据源范围
Set dataSource = ws.Range("A1:F" & lastRow)
' 定义透视表目的起始位置
' 创建一个新的数据透视表
Set newPivot = wb.PivotCaches.Create(xlDatabase, dataSource).CreatePivotTable(ws.Range("J1"), "PivotTable123")
' 定义透视表的行列值
With newPivot
.PivotFields("名称").Orientation = xlRowField
.PivotFields("商品编号").Orientation = xlRowField
.PivotFields("生产年月").Orientation = xlColumnField
With .PivotFields("销售数量")
.Orientation = xlDataField
.Function = xlSum
End With
End With
End Sub
代码阐明：
注意 PivotCaches.Create 是用在workbook反面的方法属性
CreatePivotTable 用来指定创建的透视表的位置以及透视表的名称，若想要在一张新的工作表创建，如想在sheet3中创建，则可以将上述代码中的ws.Range(“J1”)改为ThisWorkbook.Worksheets(“Sheet3”).Range(“A1”),前提是该工作簿中存在Sheet3工作表
https://i-blog.csdnimg.cn/direct/6dec50019d3f4f75941cc13f83512417.png
2. 修改数据透视表的数据源
如上例类似，修改已有的数据透视表的数据源，修改为A1：F20,完备的代码如下：
Sub UpdatePivotSourceData()
' 声明工作簿、工作表变量
Dim wb As Workbook
Dim ws As Worksheet
' 声明数据源、透视表目标起始位置、数据透视表变量
Dim dataSource As Range
Dim datePivot As Range
Dim pt As PivotTable
'设置工作簿为当前文件
Set wb = ThisWorkbook
Set ws = ThisWorkbook.Worksheets("Sheet2")
' 设置要修改的数据透视表名称
Set pt = ws.PivotTables("PivotTable123")
' 修改数据透视表的数据范围
pt.sourceData = ws.Range("A1:F20").Address(True, True, xlR1C1, True)
' 刷新数据透视表
pt.RefreshTable
End Sub
https://i-blog.csdnimg.cn/direct/dc73346912834685a28dbd7de095bcd3.png
3. 刷新数据透视表
pt.RefreshTable
pt表现对应的数据透视表，如以下代码：
Sub RefreshPivot
Dim pt As PivotTable
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("Sheet2")
' 设置要修改的数据透视表名称
Set pt = ws.PivotTables("PivotTable123")
' 刷新数据透视表
pt.RefreshTable
End Sub
对应的数据透视表名称
https://i-blog.csdnimg.cn/direct/f922b0820bee4cbea5d01e49127ad7c6.png
免责声明：如果侵犯了您的权益，请联系站长，我们会及时删除侵权内容，谢谢合作！更多信息从访问主页：qidao123.com:ToB企服之家，中国第一个企服评测及商务社交产业平台。
页:
[1]