win10使用Bat脚本主动化定时备份文件、删除特定文件和文件夹 - ToB企服应用市场:ToB评测及商务社交产业平台

@echo off
setlocal enabledelayedexpansion
:: 设置字符集为UTF-8，这将会使得控制台能够正确显示中文字符。
chcp 65001
:: 设置源文件夹和目标文件夹
set "source_folder=D:\sql\oracle\oracle文档"
set "destination_folder=D:\sql\oracle\win-backup"
:: 检查目标文件夹是否存在，如果不存在则创建
if not exist "%destination_folder%" mkdir "%destination_folder%"
:: 获取当前日期和时间，用于创建备份文件夹
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=!dt:~2,2!" & set "YYYY=!dt:~0,4!" & set "MM=!dt:~4,2!" & set "DD=!dt:~6,2!"
set "HH=!dt:~8,2!" & set "Min=!dt:~10,2!" & set "Sec=!dt:~12,2!"
set "backup_folder=%destination_folder%\%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"
:: 创建备份文件夹
mkdir "!backup_folder!"
:: 执行备份操作，使用xcopy命令复制文件夹及其内容
xcopy /E /I /Y "%source_folder%" "!backup_folder!"
:: 输出备份完成消息
echo Backup completed: !backup_folder!
endlocal
pause

复制代码

@echo off
setlocal
chcp 65001
:: 设置备份文件夹路径
set "backup_folder=D:\sql\oracle\win-backup"
:: 调用PowerShell脚本来删除三天前的文件夹
powershell -Command "$limit_date = (Get-Date).AddDays(-3); Get-ChildItem -Path '%backup_folder%' -Directory -Recurse | Where-Object { $_.LastWriteTime -lt $limit_date } | Remove-Item -Recurse -Force; Write-Host 'Deleted backup folders older than 3 days.'"
:: 输出完成消息
echo Deleted backup folders older than 3 days.
endlocal
pause

复制代码