delphi JSON序列化（四）

涉及的重要类 REST.Json，REST.JsonReflect，REST.Json.Interceptors, REST.Json.Types单元中。
一、TJson类
最简单的一个类，提供了JSON -> OBJECT和OBJECT -> JSON几个方法，方法有TJsonOptions参数，如：
    class function ObjectToJsonObject(AObject: TObject; AOptions: TJsonOptions = CDefaultOptions): TJSONObject;

1. type
2.   TJsonOption = (joIgnoreEmptyStrings, joIgnoreEmptyArrays,
3.     joDateIsUTC, joDateFormatUnix, joDateFormatISO8601, joDateFormatMongo, joDateFormatParse,
4.     joBytesFormatArray, joBytesFormatBase64,
5.     joIndentCaseCamel, joIndentCaseLower, joIndentCaseUpper, joIndentCasePreserve,
6.     joSerialFields, joSerialPublicProps, joSerialPublishedProps, joSerialAllPubProps);
7.   TJsonOptions = set of TJsonOption;

复制代码

TJsonOptions主要是控制一些转换细节，如日期类型的格式，Base64, 驼峰，属性的可见性等。
二、TConverter 类
这是一个抽象类，提供了序列化过程中的相关方法
三、  TJSONConverter = class(TConverter)
是TConverter 类的子类，实现了父类的抽象方法，同时也是默认的转换器。
四、TJSONMarshal和TJSONUnMarshal
这个类是正、反序列化的两个具体类。TJson内部就是使用这两个类完成工作的。
五、一些TCustomAttribute的子类
这些子类是“贴标签”用的，  如JSONMarshalledAttribute和JsonNameAttribute

1.   TPerson = class
2.   private
3.     fname: string;
4.     fage: Integer;
5.   public
6.     [JsonName('_new_name_')]
7.     property name: string read fname write fname;
8.     [JSONMarshalled(false)]
9.     property age: Integer read fage write fage;
10.   end;<br>//json结果 ：  {"_new_name_":"aaa"}

复制代码

六、TJSONConverters类
这个类有几个静态方法，可以添加转换事件类。
七、TConverterEvent和TReverterEvent
这两个类是成对的，主要是定义了拦截事件。
八、TJSONInterceptor类
可以自定义不同的TJSONInterceptor子类，然后供JsonReflectAttribute属性标签用。
九、简单的示例

1. unit Unit1;
3. interface
5. uses
6.   Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
7.   Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.Buttons, Rest.JSON.Types, Rest.JsonReflect;
9. type
10.   TForm1 = class(TForm)
11.     Memo1: TMemo;
12.     procedure FormCreate(Sender: TObject);
13.   private
14.     { Private declarations }
15.   public
16.     { Public declarations }
17.   end;
19.   TTestInterceptor = class(TJSONInterceptor)
20.   public
21.     function StringConverter(Data: TObject; Field: string): string; override;  // 注意事项 2： 这个方法实现要追加的字符串。
22.     function TypeObjectConverter(Data: TObject): TObject; override;     //注意事项一：转换对象的这个方法一定要实现，
23.   end;
25.   [JSONSerialize(jmPublicProps)]  //
26.   [JsonReflect(ctTypeObject, rtTypeObject, TTestInterceptor)] //注意事项一：偷换了转换的对象，
27.   TPerson = class
28.   private
29.     fname: string;
30.     fage: Integer;
31.   public
32.     constructor Create(_name: string; _age: Integer);
33.     property name: string read fname write fname;
34.     property age: Integer read fage write fage;
35.   end;
37.   [JSONSerialize(jmPublicProps)]
38.   TPerson2 = class
39.   private
40.     fname: string;
41.     fage: Integer;
42.   public
43.     constructor Create;
44.     [JsonReflect(ctString, rtString, TTestInterceptor)]    //注意事项 2 ：字符串属性内容转换。
45.     [JsonName('new_name_')]
46.     property name: string read fname write fname;
47.     [JSONMarshalled(false)]
48.     property age: Integer read fage write fage;
49.   end;
51. var
52.   Form1: TForm1;
54. implementation
56. {$R *.dfm}
58. uses
59.   REST.Json, System.Generics.Collections;
61. { TPerson }
63. constructor TPerson.Create(_name: string; _age: Integer);
64. begin
65.   inherited Create;
66.   fname := _name;
67.   fage := _age;
68. end;
70. { TPerson2 }
72. constructor TPerson2.Create;
73. begin
74.   inherited Create;
75.   fname := 'person222222';
76. end;
78. procedure TForm1.FormCreate(Sender: TObject);
79. begin
80.   var p := TPerson.Create('aaa', 1);
81.   var jsonValue := TJson.ObjectToJsonObject(p, [joIndentCaseUpper]);  // 注意：自定义转换后，name不会转为大写。
82.   Memo1.Text := jsonValue.toString;
83.   p.Free;
84. end;
86. { TTestInterceptor }
88. function TTestInterceptor.StringConverter(Data: TObject; Field: string): string;
89. begin
90.   Result := RTTIProvider.GetMember(Data, Field).GetValue(Data).AsString + '__新加的内容';
91. end;
93. function TTestInterceptor.TypeObjectConverter(Data: TObject): TObject;
94. begin
95.   //这里偷换为 person2.
96.   Result := TPerson2.Create;
97. end;
99. end.

复制代码

View Code结果：{"new_name_":"person222222__新加的内容"}
 

免责声明：如果侵犯了您的权益，请联系站长，我们会及时删除侵权内容，谢谢合作！